Conversion cassettes MO5 en disquettes et fichiers .sd

Cette catégorie traite de développements récents pour nos vieilles machines, applications, jeux ou démos... Amis programmeurs, c'est ici que vous pourrez enfin devenir célèbres!

Modérateurs : Papy.G, fneck, Carl

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 08 mars 2015 17:52

Conversion en disquette et carte SD de la cassette "Les Hits de Loriciels 1" pour MO5 : Eliminator, Pulsar II, Yéti.

Dans cette conversion la même méthode pas très subtile a été utilisée pour les trois programmes : chargement à partir de secteurs physiques de la disquette en $6000, puis recopie en $2000 avec écrasement des vecteurs du moniteur, des vecteurs du Basic et du DOS. Le programme de sélection a été reconstitué de toutes pièces en prenant modèle sur la version TO8.
http://dcmoto.free.fr/programmes/les-hi ... index.html

Image Image
Image Image

Code : Tout sélectionner

*****************************
* CHARGEUR HITS LORICIELS   *
* Daniel Coulom 2015/03/07  *
*****************************

 
***************************** 
* En-tete complementee
* avec checksum
***************************** 
  ORG  $2200       adresse de debut 
  FDB  $E082       $207E complemente
  ORG  $227F       adresse checksum 
  FCB  $F3         checksum

*****************************  
* Chargement suite du loader
*****************************  
LECT1
  LDS    #$2800             
  LDA    #$20               
  TFR    A,DP               
  LDD    #$0002     piste 0 secteur 2           
  LDX    #$2300     buffer en $2300          
  CLR    <$4A               
  STA    <$4B       numero piste               
  STB    <$4C       numero secteur           
  CLR    <$49       code erreur           
  STX    <$4F       adresse buffer           
  LDA    #$02       code lecture secteur           
  STA    <$48       code operation           
  SWI               appel fonction systeme          
  FCB    $26        lecture secteur

*****************************  
* Presentation et choix
*****************************  
  LDY    #NOMS      nom des programmes         
  LBSR   AFFICH     affichage nom des programmes        
PRES1
  SWI               appel fonction systeme       
  FCB    $0A        scrutation clavier
  ANDB   #$DF               
  TSTB              test de la touche        
  BEQ    PRES1      pas de touche pressee              
  CMPB   #$59       'Y'   
  BEQ    PRES3      chargement Yeti          
  CMPB   #$50       'P'    
  BEQ    PRES2      chargement Pulsar          
  CMPB   #$45       'E'  
  BNE    PRES1      nouvelle saise      
* chargement eliminator
  LBSR   DISPLAY    affichage copyright        
  LDA    #$01       piste de debut = 1        
  BRA    RUN
* chargement pulsar
PRES2
  LBSR   DISPLAY    affichage copyright        
  LDA    #$05       piste de debut = 5        
  BRA    RUN
* chargement yeti
PRES3
  LBSR   DISPLAY    affichage copyright        
  LDA    #$09       piste de debut = 9        
  BRA    RUN

*****************************  
* Translation et execution
*****************************  
RUN
  BSR    CHARG      chargement programme en $6000        
* transfert en $1F40 du programme de translation
  LDX    #$1F40
  LDY    #TRANS
PRES5
  LDD    ,y++
  STD    ,X++
  CMPX   #$1F60
  BNE    PRES5
  JMP    $1F40      execution translation 

*****************************  
* Lecture secteur
*****************************  
RSECT
  PSHS   Y                  
  LDY    #$2048             
  CLR    $02,Y              
  STA    $03,Y              
  STB    $04,Y              
  CLR    $01,Y              
  STX    $07,Y              
  LDA    #$02               
  STA    ,Y                 
  SWI               appel fonction systeme
  FCB    $26        lecture secteur      
  PULS   Y,PC               

*****************************  
* Chargement programme
*****************************  
CHARG
  LDX    #$6000       chargement en $6000        
  TFR    A,B          numero de piste courante      
  ADDB   #$04         calcul piste de fin          
  STB    CHARG2+1     modifie test piste de fin        
  LDB    #$01         secteur 1         
CHARG1
  PSHS   X,B,A              
  BSR    RSECT        lecture secteur           
  PULS   A,B,X               
  LEAX   $0100,X      buffer suivant          
  INCB                secteur suivant          
  CMPB   #$11         test secteur 17          
  BNE    CHARG1              
  LDB    #$01         secteur 1          
  INCA                piste suivante          
CHARG2
  CMPA   #$00         test piste de fin          
  BNE    CHARG1             
  RTS                       

***********************************  
* Translation et execution du jeu
* routine transferee en $1F40
***********************************
TRANS
  LDS    #$1FFF       pointeur de pile systeme 
  LDD    $2073        adresse table des caracteres
  PSHS   D            empilage adresse table
  LDX    #$2000       adresse destination
  LDY    #$6000       adresse origine
TRANS1
  LDD    ,y++         origine
  STD    ,X++         destination
  CMPX   #$5C00       test fin du transfert
  BNE    TRANS1       nouveau transfert
  PULS   D            depilage adresse table
  STD    $9A00        stockage en $9A00 
  JMP    $2000        execution du jeu   

*****************************  
* Affichage copyright
*****************************  
DISPLAY
  LDY    #ECRAN          

*****************************  
* Affichage d'une chaine
*****************************  
AFFICH
  LDB    ,Y+                
  BEQ    AFFICH9             
  SWI               appel fonction systeme
  FCB    $02        affichage caractere   
  BRA    AFFICH           
AFFICH9
  RTS                       

*****************************  
* Donnees
*****************************  
ECRAN
  FCB   $1b,$64,$1b,$47,$1b,$54,$0c
  FCB   $20,$20,$20,$20,$20,$20
  FCB   $43,$6f,$70,$79,$72,$69,$67,$68,$74 'Copyright'
  FCB   $20
  FCB   $4c,$6f,$72,$69,$63,$69,$65,$6c,$73 'Loriciels'
  FCB   $20
  FCB   $31,$39,$38,$37                     '1987'
  FCB   $0a,$0d,$0a,$0a,$0a,$0a,$00
NOMS
  FCB   $1b,$54,$1b,$64,$1b,$47,$0c
  FCB   $1b,$73,$1f,$48,$4a,$1b,$7b,$59     'Y' 
  FCB   $1b,$72,$1b,$7b,$45,$54,$49         'ETI' 
  FCB   $1f,$4b,$4a,$1b,$73,$1b,$7b,$50     'P'
  FCB   $1b,$72,$1b,$7b,$55,$4c,$53,$41,$52 'ULSAR'
  FCB   $1f,$4e,$4a,$1b,$7b,$1b,$73,$45     'E'
  FCB   $1b,$72,$1b,$7b
  FCB   $4c,$49,$4d,$49,$4e,$41,$54,$4f,$52 'LIMINATOR' 
  FCB   $1b,$70,$00

*****************************  
* Completer a $1000 octets
*****************************  
  ORG   $31FF
  FCB   $00
 
  END
Daniel
L'obstacle augmente mon ardeur.

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 10 mars 2015 17:45

Conversion en disquette et carte SD de la cassette "Le 5eme Axe" pour MO5.

Il y a deux parties dans le 5eme Axe :
1) La consultation de la documentation et les règles du jeu.
2) Le jeu lui-même

Pour la première partie j'ai tout réécrit pour translater le programme au-delà de l'adresse haute du DOS.
Pour la deuxième partie ce n'est pas possible car le programme est trop grand. J'ai utilisé la méthode "brute" : loader en mémoire vidéo chargeant des secteurs physiques de la disquette, en écrasant le DOS.
http://dcmoto.free.fr/programmes/le-5eme-axe/index.html

Image Image
Image Image

Code : Tout sélectionner

********************************
*  CHARGEUR JEU Le 5eme Axe    *
*  Daniel Coulom - 08/03/2015  *
********************************
*
* Preparation du chargement
* Trois programmes differents :
* - Affichage 1er ecran d'attente
* - Menu d'acces aux documents
* - Affichage 2eme ecran d'attente

ECRANS EQU $6000

  ORG    $5000
  BRA    DATT        $5000=ecran d'attente
  NOP
  LBRA   MENU        $5003=menu des options
  LBRA   JEU         $5006=chargement du jeu

********************************  
* Affichage ecran attente
********************************  
DATT
  LDX    #ECRAN1      adresse donnees ecran             
DATT1
  LDB    ,X+                
  BEQ    DATT9            
  SWI
  FCB    $02          affichage ecran           
  BRA    DATT1           
DATT9
  RTS            

********************************  
* DONNEES ECRAN1
********************************  
ECRAN1
  FCB $1b,$44,$1b,$57,$0c
  FCB $1b,$67,$0a,$0a
  FCB $1b,$73,$0d,$0a
  FCB $09,$20,$20,$20,$20,$4c,$65,$20
  FCB $35,$16,$41,$65,$6d,$65,$20,$41
  FCB $58,$45,$1b,$70,$0d,$0a,$0a,$20
  FCB $27,$47,$61,$72,$65,$20,$16,$41
  FCB $61,$20,$76,$6f,$73,$20,$74,$16
  FCB $43,$65,$74,$65,$73,$2c,$20,$6c
  FCB $27,$55,$6e,$69,$76,$65,$72,$73
  FCB $20,$62,$61,$73,$63,$75,$6c,$65
  FCB $2e,$27,$0d,$0a,$0a,$1b,$45,$20
  FCB $20,$20,$20,$20,$20,$44,$69,$64
  FCB $69,$65,$72,$20,$65,$74,$20,$4f
  FCB $6c,$69,$76,$69,$65,$72,$20,$47
  FCB $55,$49,$4c,$4c,$49,$4f,$4e,$0d
  FCB $0a,$0a,$20,$20,$20,$20,$20,$20
  FCB $20,$20,$20,$20,$20
  FCB $1b,$51,$1b,$47
  FCB $28,$63,$29,$20,$4c,$4f,$52,$49
  FCB $43,$49,$45,$4c,$53,$20,$31,$39
  FCB $38,$35
  FCB $1b,$40,$1b,$57
  FCB $0d,$0a,$0a,$0a,$53,$41,$56,$49
  FCB $45,$5a,$2d,$56,$4f,$55,$53,$20
  FCB $51,$55,$45,$3a,$0d,$0a,$0a,$2d
  FCB $4e,$6f,$75,$73,$20,$73,$6f,$6d
  FCB $6d,$65,$73,$20,$65,$6e,$20,$32
  FCB $34,$31,$30,$3f,$0d,$0a,$2d,$56
  FCB $6f,$75,$73,$20,$70,$61,$72,$61
  FCB $69,$73,$73,$65,$7a,$20,$70,$6c
  FCB $75,$73,$20,$63,$6f,$73,$74,$61
  FCB $75,$64,$20,$71,$75,$65,$20,$76
  FCB $6f,$75,$73,$20,$65,$6e,$20,$20
  FCB $61,$76,$65,$7a,$20,$6c,$27,$61
  FCB $69,$72,$3f,$0d,$0a,$2d,$4c,$65
  FCB $20,$63,$68,$61,$72,$67,$65,$6d
  FCB $65,$6e,$74,$20,$65,$73,$74,$20
  FCB $65,$6e,$20,$63,$6f,$75,$72,$73
  FCB $3f,$00


***********************************
* Affichage document B
***********************************
DDOC
  PSHS   DP                 
  LDA    #$24               
  TFR    A,DP               
  CLR    <$00               
  CLR    <$01               
  CLR    <$02               
  LDX    #ECRANS             
DDOC01
  LDA    ,X+                
  BNE    DDOC01             
  DECB                   
  BNE    DDOC01      sauter B chaines         
DDOC02
  LDB    ,X+        
  CMPB   #$24        '$'
  BNE    DDOC03      
  COM    <$00     
  BRA    DDOC02   
DDOC03
  CMPB   #$40        '@'
  BNE    DDOC04      
  COM    <$01   
  BRA    DDOC02   
DDOC04
  CMPB   #$23        '#'
  BNE    DDOC05   
  COM    <$02   
  BRA    DDOC02      
DDOC05
  CMPB   #$5E        '^'
  BNE    DDOC08        
  LDA    ,X+         nombre ASCII
  SUBA   #$30        nombre binaire
  STA    <$03        numero colonne    
  LDD    $2021       position caractere courant 
  SUBD   #$0028      ligne au-dessus
  SUBB   <$03        retrancher numero colonne
  SBCA   #$00   
  STD    <$05        debut ligne precedente
  LDA    #$01   
  STA    <$04   
  SWI
  FCB    $06         video forme 
  LDA    <$04   
DDOC06
  LDY    <$05        debut ligne precedente
  LDB    <$03        numero colonne
  ANDCC  #$FE        raz carry    
DDOC07
  ROR    ,Y+     
  DECB          
  BPL    DDOC07   
  DECA         
  BNE    DDOC06      
  LDD    <$05  
  SUBD   #$0028
  STD    <$05  
  INC    <$04  
  LDA    <$04  
  CMPA   #$08  
  BNE    DDOC06     
  BRA    DDOC02      
DDOC08
  CMPB   #$00         
  BNE    DDOC10     
  PULS   DP,PC      retour
DDOC10              
  TSTB         
  BPL    DDOC11     affichage caractere
  LDB    #$1B       ECHAP
  SWI
  FCB    $02        affichage sequence ECHAP
  LDB    -$01,X 
  ANDB   #$7F   
  SWI    
  FCB    $02        affichage code sequence ECHAP
  BRA    DDOC02      
DDOC11
  LDY    $2021      position caractere courant  
  SWI
  FCB    $02        affichage caractere
  CMPB   #$0D       test CR
  BNE    DDOC12     ce n'est pas CR
  LDB    #$0A       ajout $0A apres CR
  SWI
  FCB    $02        affichage caractere
DDOC12    
  CMPB   #$21    
  LBCS   DDOC02      
  LDA    $A7C0      
  ORA    #$01       
  STA    $A7C0      selection video forme
  LDA    <$00  
  BEQ    DDOC13   
  LDA    #$FF   
  STA    ,Y     
DDOC13             
  LDA    <$02     
  BEQ    DDOC14   
  BSR    DDOC20  
DDOC14   
  LDA    <$01    
  BEQ    DDOC15 
  LEAY   $FF60,Y        
  BSR    DDOC20          
DDOC15
  LBRA   DDOC02  

******************************
*
******************************
DDOC20
  PSHS   Y                  
  LDB    #$04               
DDOC21
  LDA    ,Y                 
  ASLA                      
  ORA    ,Y                 
  STA    ,Y                 
  LEAY   -40,Y              
  DECB                      
  BNE    DDOC21              
  PULS   Y,PC               

******************************
* CHAINAGE DES ECRANS
******************************
SHOW
  PSHS   A    
SHOW1                
  BSR    SHOW2              
  INCB                      
  CMPB   ,S                 
  BLS    SHOW1              
  PULS   A,PC               

******************************
* TRAITEMENT D'UN ECRAN
******************************
SHOW2
  PSHS   B                  
  LBSR   DDOC    afficher document              
  LDB    #$1E               
  SWI
  FCB    $02     affichage caractere           
  LDA    #$18               
  LDB    #$0A               
SHOW3
  SWI
  FCB    $02     affichage caractere               
  DECA                      
  BNE    SHOW3              
  LDB    $202B              
  PSHS   B                  
  LDB    #$14               
  LBSR   DDOC    afficher document              
  PULS   B                  
  STB    $202B
SHOW4                
  SWI
  FCB    $0A     lecture clavier               
  TSTB                      
  BEQ    SHOW4              
  PULS   B,PC               

******************************
* MENU DES OPTIONS
******************************
MENU
  LBSR   INIT              
  LDA    #$08               
  STA    $2019              
  LDA    #$21               
  TFR    A,DP               
MENU01
  LDB    #$12              
  LBSR   DDOC    affichage ecran d'accueil               
MENU02
  SWI
  FCB    $0A     lecture clavier             
  CMPB   #$33    '3' Debuter ta mission        
  BNE    MENU06         
  RTS            retour au Basic 
MENU06
  CMPB   #$32    '2' Etudier tes moyens d'action             
  BNE    MENU07         
  LDB    #$15       
  LDA    #$19       
  BSR    SHOW      
  BRA    MENU01  affichage du menu    
MENU07
  CMPB   #$31    '1' Consulter les documents joints            
  BNE    MENU02  nouveau choix          
  LDB    #$01               
  LDA    #$03               
  BSR    SHOW              
MENU08
  LDB    #$13               
  LBSR   DDOC              
MENU09
  SWI
  FCB    $0A               
  ANDB   #$DF               
  CMPB   #$41               
  BNE    MENU11              
  LDB    #$04               
  LDA    #$09               
MENU10
  BSR    SHOW              
  BRA    MENU08              
MENU11
  CMPB   #$42               
  BNE    MENU12              
  LDB    #$0A               
  LDA    #$0C               
  BRA    MENU10              
MENU12
  CMPB   #$43               
  BNE    MENU13              
  LDB    #$0D               
  LDA    #$0F               
  BRA    MENU10              
MENU13
  CMPB   #$44               
  BNE    MENU14              
  LDB    #$10               
  LDA    #$11               
  BRA    MENU10              
MENU14
  CMPB   #$45               
  BNE    MENU09              
  BRA    MENU01               

******************************
* INITIALISATIONS
******************************
INIT
  ORCC   #$D0               
  LDA    #$7E               
  LDX    #MENU             
  STA    $228A              
  STX    $228B              
  LDX    #$2290             
INIT1
  CLR    ,X+                
  CMPX   #$238F           
  BNE    INIT1              
  LDA    #$39               
  STA    $2278              
  STA    $227B              
  STA    $227E              
  STA    $2284              
  STA    $2287              
  RTS                       

******************************
* CHARGEMENT DU JEU
******************************
JEU
  LDX    #ECRAN2     ecran d'attente       
JEU1
  LDB    ,X+                
  BEQ    JEU2              
  SWI
  FCB    $02         affichage ecran         
  BRA    JEU1            
JEU2
  RTS

********************************  
* DONNEES ECRAN2
********************************  
ECRAN2
  FCB $1b,$40,$1b,$57
  FCB $0c,$0a,$0a,$0a,$0a,$0a,$20,$43
  FCB $69,$74,$6f,$79,$65,$6e,$2c,$0d
  FCB $0a,$0a,$20,$4c,$61,$20,$73,$6f
  FCB $63,$69,$16,$42,$65,$74,$16,$42
  FCB $65,$20,$4c,$4f,$52,$49,$43,$49
  FCB $45,$4c,$53,$20,$49,$6e,$74,$65
  FCB $72,$67,$61,$6c,$61,$63,$74,$69
  FCB $71,$75,$65,$0d,$0a,$20,$74,$65
  FCB $20,$73,$6f,$75,$68,$61,$69,$74
  FCB $65,$20,$62,$6f,$6e,$20,$74,$72
  FCB $61,$6e,$73,$69,$74,$20,$65,$74
  FCB $20,$74,$65,$20,$64,$65,$6d,$61
  FCB $6e,$64,$65,$20,$20,$20,$64,$65
  FCB $20,$67,$61,$72,$64,$65,$72,$20
  FCB $74,$6f,$6e,$20,$63,$61,$6c,$6d
  FCB $65,$20,$64,$75,$72,$61,$6e,$74
  FCB $20,$6c,$61,$20,$70,$16,$42,$65
  FCB $72,$69,$6f,$64,$65,$20,$20,$20
  FCB $64,$65,$20,$72,$16,$42,$65,$6f
  FCB $72,$67,$61,$6e,$69,$73,$61,$74
  FCB $69,$6f,$6e,$20,$6d,$6f,$6c,$16
  FCB $42,$65,$63,$75,$6c,$61,$69,$72
  FCB $65,$2e,$0d,$0a,$0a,$44,$16,$42
  FCB $65,$70,$61,$72,$74,$20,$3a,$20
  FCB $4e,$6c,$6c,$65,$2d,$4d,$65,$6c
  FCB $62,$6f,$75,$72,$6e,$65,$2c,$20
  FCB $20,$20,$20,$20,$31,$35,$68,$20
  FCB $35,$33,$20,$6d,$6e,$0d,$0a,$0a
  FCB $41,$72,$72,$69,$76,$16,$42,$65
  FCB $65,$3a,$20,$50,$6c,$61,$6e,$16
  FCB $42,$65,$74,$6f,$16,$48,$69,$64
  FCB $65,$20,$47,$50,$20,$33,$32,$32
  FCB $20,$41,$2c,$31,$35,$68,$20,$35
  FCB $36,$20,$6d,$6e,$1b,$62,$00

  END

Code : Tout sélectionner

********************************
*  CHARGEUR JEU LE 5EME AXE    *
*  Daniel Coulom - 10/03/2015  *
********************************
*
* Le chargeur initialise la 
* RAM du MO5 de $25A4 a $9EFC
* et lance le jeu en $795E.
* Le dump memoire est dans
* les secteurs physiques de
* la disquette a partir du 
* secteur 1 de la piste 3.

*****************************  
* Lecture memoire
* $25A4-$9EFC
*****************************  
  ORG  $1F40
  LDS  #$9FFF   pile systeme
  LDA  #$20     valeur pour DP
  TFR  A,DP     initialise DP
  LDA  #$02     lecture secteur
  STA  <$48     code commande
  LDX  #$25A4   adresse du buffer
  LDD  #$0300   piste et secteur
LECT  
  INCB          secteur suivant 
  BSR  LSECT    lecture secteur
  LEAX 256,X    buffer suivant
  CMPX #$9FA4   test de fin
  BEQ  FIN      chargement termine
  CMPB #$10     test secteur 16
  BNE  LECT     secteur suivant
  INCA          piste suivante
  CLRB          raz secteur
  BRA  LECT     secteur suivant
FIN  
  JMP  $795E  
  
*****************************  
* Lecture secteur B piste A
* Adresse du buffer dans X
*****************************  
LSECT
  STX  <$4F    adresse du buffer
  STD  <$4B    piste et secteur
  JSR  $A004   lecture secteur
  RTS
  
  END
Daniel
L'obstacle augmente mon ardeur.

Avatar du membre
6502man
Messages : 10163
Enregistré le : 12 avr. 2007 22:46
Localisation : VAR
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par 6502man » 10 mars 2015 20:10

encore du très bon travail :D
Phil.

www.6502man.com

To bit or not to bit.
1 or 0.

Avatar du membre
Papy.G
Modérateur
Messages : 2345
Enregistré le : 10 juin 2014 13:40
Localisation : Haute-Garonne/Gers

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Papy.G » 10 mars 2015 20:52

Je n'ai pas de Thomson (pour l'instant :mrgreen: ), mais je suis admiratif de tout ce boulot, d'accord, une fois trouvé l'astuce, c'est plus facile pour les suivants, mais ça ne se fait pas tout seul quand-même.

Merci Daniel, au nom de tous ceux qui, dans cinq ans, dix ans, vingt ans ou bien plus, pourront toujours utiliser ces logiciels, sur émulateur ou vraies machines, malgré que les bandes auront perdu leurs oxydes.

En fait, c'est mieux que du SAV, mieux que si Thomson avait juste prolongé le support de ces machines, avec ton boulot, tu arrives à donner envie à des jeunes qui n'ont jamais connu ces machines à s'en servir, à jouer à ces jeux.

Ca compte aussi pour Sam, Phil, et tous ceux ici qui font du rafraîchissement, du logiciel, du matériel, pour ces machines abandonnées.
Soyez exigeants, ne vous contentez pas de ce que l'on vous vend.
Demandez-en plus, ou faites-le vous-même.

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 10 mars 2015 21:14

Il faut savoir que ces conversions ont été possibles après avoir compris et contourné la protection des cassettes, parfois assez diabolique (le 5ème axe est un bon exemple de ce qui se faisait de mieux à l'époque). La sauvegarde des cassettes MO5 et leur déprotection est un travail de longue haleine (j'y ai passé au moins 25 ans).

Aujourd'hui je connais bien les programmes, leur conversion en disquettes n'est pas trop difficile : pas plus d'un ou deux jours par jeu. C'est la cerise sur le gâteau :wink:

Les disquettes sont beaucoup plus fiables et plus rapides que les cassettes, mais ce n'est pas l'objectif principal : comme les cassettes, ce support disparaîtra un jour et les lecteurs tomberont en panne. Par contre les versions sur carte SD ou autres supports modernes risquent de durer plus longtemps. Et c'est beaucoup plus pratique à utiliser, n'en déplaise aux amoureux de la cassette :wink:
Daniel
L'obstacle augmente mon ardeur.

Avatar du membre
Papy.G
Modérateur
Messages : 2345
Enregistré le : 10 juin 2014 13:40
Localisation : Haute-Garonne/Gers

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Papy.G » 10 mars 2015 21:22

Oui, c'est la raison pour laquelle je n'utilisais pas mon Oric, et m'en suis finalement débarrassé, les cassettes, c'est pénible, je serais tombé sur une solution équivalente à ce que vous avez sur Thomson, à savoir support SD et convertisseurs de cassettes, je l'aurais peut-être gardé, c'est une machine sympa et peu encombrante.
Soyez exigeants, ne vous contentez pas de ce que l'on vous vend.
Demandez-en plus, ou faites-le vous-même.

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 13 mars 2015 14:55

Nouvelles conversions :

Vox : http://dcmoto.free.fr/programmes/vox-basic/index.html
Démonstration : Image

Image Image


Parole (uniquement la démonstration) : http://dcmoto.free.fr/programmes/parole/index.html
Démonstration : Image

Image Image


Vol Solo : http://dcmoto.free.fr/programmes/vol-solo/index.html

Image Image

Pour ces conversions, utilisation de la technique habituelle lorsque le programme est incompatible avec le DOS : un chargeur en mémoire vidéo lit le fichier binaire dans des secteurs physiques de la disquette, l'implante en mémoire en écrasant le DOS et lance l'exécution.

Cas particulier pour Parole : les cassettes MO5 n'ont pas encore été transférées sur PC. A l'occasion je lance un appel aux collectionneurs pour les retrouver et les numériser. En l'absence de programmes MO, j'ai porté la version TO sur MO5, mais uniquement la démonstration de synthèse vocale. Phonétram et Normaphon ne sont pas dans la disquette MO5.
Daniel
L'obstacle augmente mon ardeur.

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 15 mars 2015 08:12

Nouvelle conversion :
Brain Power : http://dcmoto.free.fr/programmes/brain-power/index.html

Image Image

Toujours la même méthode pour le jeu : chargeur en mémoire vidéo pour lire le programme dans les secteurs physiques de la disquette. Ici l'implantation est en $2120-$9FFF, donc les zones de travail du Basic et le DOS sont écrasés. Pour l'affichage de l'image de présentation j'ai gardé le programme original, implanté en $5E00, donc compatible avec le DOS.
Daniel
L'obstacle augmente mon ardeur.

petitjd
Messages : 1901
Enregistré le : 23 oct. 2007 11:50

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par petitjd » 15 mars 2015 08:34

Ah ha, je me doutais que tu bossais sur cette conversion, cf le bas de ta capture d'écran de dcmoto sous OS9 dans le fil de discussion de Jacques ;)
http://forum.system-cfg.com/viewtopic.p ... =15#p99838
PetitJD
Tortue Jeulin: www.tortue-jeulin.com
Nanoreseau: www.nanoreseau.net
Proteus III: www.proteus-international.fr

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 17 mars 2015 15:39

As-tu deviné cette nouvelle conversion ?

Sapiens : http://dcmoto.free.fr/programmes/sapiens/index.html

Image Image

Présentation avec un programme assembleur lancé en Basic. Chargeur en mémoire vidéo pour le jeu.

Vu l'intérêt suscité par ces conversions je vais arrêter. Elles m'ont replongé, avec toujours autant de plaisir, dans l'étude des protections des cassettes MO5. Les programmeurs de cette époque étaient doués et avaient beaucoup d'imagination...

J'ai maintenant suffisamment de jeux MO5 sur carte SD pour faire des démonstrations de chargement à la prochaine visu 8)
Daniel
L'obstacle augmente mon ardeur.

__sam__
Messages : 5403
Enregistré le : 18 sept. 2010 12:08
Localisation : Brest et parfois les Flandres

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par __sam__ » 17 mars 2015 16:42

Tes portages de jeu devraient intéresser ceux qui ont un MO5 en démonstration dans les expositions retro. Le chargement depuis SD est bien plus fiable et rapide que la K7 quand il y a pleins de visiteurs. Combiné à SDBoot, ca doit faire compilation superbe avec tous ces jeux portés sur D7/SD.
Samuel.
A500 Vampire V2+ ^8^, A1200(030@50mhz/fpu/64mb/cf 8go),
GVP530 (MMU/FPU) h.s., R-Pi, TO9, TO8D, TO8.

Avatar du membre
6502man
Messages : 10163
Enregistré le : 12 avr. 2007 22:46
Localisation : VAR
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par 6502man » 17 mars 2015 20:05

Daniel tu fait un travail formidable, mais la foule est tellement subjuguée quelle en perd la voix et l'écriture :wink:
Phil.

www.6502man.com

To bit or not to bit.
1 or 0.

Avatar du membre
Carl
Modérateur
Messages : 11246
Enregistré le : 08 avr. 2007 13:21
Localisation : http://www.doledujura.fr
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Carl » 17 mars 2015 22:10

Merci Daniel pour ces conversions !
j'aurai au moins quelques titres à faire tourner sur mon Mo5 Bibus :wink:

Carl

petitjd
Messages : 1901
Enregistré le : 23 oct. 2007 11:50

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par petitjd » 18 mars 2015 00:16

En fait, je ne sais pas comment tu fais pour connaitre aussi bien voir même mieux le MO5 que ses concepteurs!
PetitJD
Tortue Jeulin: www.tortue-jeulin.com
Nanoreseau: www.nanoreseau.net
Proteus III: www.proteus-international.fr

Daniel
Messages : 12957
Enregistré le : 01 mai 2007 18:30
Localisation : Vaucluse
Contact :

Re: Conversion cassettes MO5 en disquettes et fichiers .sd

Message par Daniel » 18 mars 2015 09:34

Pour bien connaître une machine, il faut l'avoir émulée, mais ça ne suffit pas. Après trente années de recherches j'en apprends encore chaque jour sur le MO5. Comme je l'ai déjà dit un ordinateur est un jouet inépuisable, je ne me suis pas encore lassé 8)
Daniel
L'obstacle augmente mon ardeur.

Répondre