Bonjour, Michel,
Bien entendu tant que le prototype est pas entièrement testé ont va pas crée un PCB, quoique vu les tarifs de nos amis les chinois !!!
Sinon voici un petit programme pour tester le screen 8 avec usage de la commande HMMM,
avec une animation pour démontrer la puissance et l'intérêt de ce VDP :
Tu peux tester aussi d'autre commande en changeant la ligne 219 en modifiant la valeur de A par $90 pour LMMM par exemple .
Code : Tout sélectionner
;***************************************
;
; TAVERNIER + VDP 9938
;
; test 256x212 256colors
;
; (c) 2020 6502MAN
;
;***************************************
; VDP I/O Ports
;---------------
VDPCTRL .EQU $E101 ; PORT #1
VDPDATA .EQU $E100 ; PORT #0
VDPPALETTE .EQU $E102 ; PORT #2
VDPRegInd .EQU $E103 ; PORT #3 ; registres indirectes
; ecrire registres : DATA port #1 ensuite Reg +80h port #1
Coordy .EQU $0000
.org $4000
Main:
JSR ModeGfx
JSR ClearVRAM
JSR WaitIntVDP
Bmp2VRAM: ; ecrit en VRAM
LDD #$0000 ; les données
LDX #$0000 ; de l'image
JSR SetVDPAddress ; stock en début de VRAM
LDX #SCREEN ; X= adresse des datas
LDY #$3E00 ; Y= longeur
JSR FillVram ; rempli VRAM
LDA #$00 ; iniatilise coordonnee Y
LDU #Coordy ;
LDA ,U ;
MOVE:
JSR Moving
BRA MOVE
FIN:
;------------------------------------------------------------------
; ROUTINES DE SERVICE
;
;
;-------------------------------------------
; Fixe le mode du VDP en mode SCREEN8
; bitmap 256x212 en 256 couleurs
;-------------------------------------------
ModeGfx:
LDB #24 ; 12 registres à ecrires
LDX #RegGfx ; adresse des données
LDU #VDPCTRL ; adresse ecriture registre VDP
LoopInitVdp:
LDA ,X+
STA ,U ; WRITE data
DECB
BNE LoopInitVdp
RTS
RegGfx:
; R0 R1 R2 =$1800 R3=$2000 R4=$0000 R5 R6 R7
FCB $02,$80, $60,$81, $06,$82, $ff,$83, $03,$84, $36,$85, $07,$86, $01,$87
; R8 R9 R10 R11
FCB $08,$88, $02,$89, $00,$8a ,$00,$8b
;-------------------------------------------
; Efface intégralement la VRAM du VDP MSX2 $1FFFF (128K)
;-------------------------------------------
ClearVRAM:
LDD #$0000
LDX #$0000
JSR SetVDPAddress ; $0.0000
LDY #$FFFF
LDA $00
LDU #VDPDATA
ClearVRAMLoop:
STA ,U ; Write data sur P1
LEAY -1,Y
BNE ClearVRAMLoop
RTS
;-------------------------------------------
; Fixe l'adresse d'ecriture du VDP
; VRAM 00000h-1FFFFh
; { Reg #45 = 0 MSX MXD MXS DIY DIX EQ MAJ } not necessary
; Reg #14 = 0 0 0 0 0 A16 A15 A14
; PORT #1 = A7 A6 A5 A4 A3 A2 A1 A0
; PORT #1 = 0 R/W A13 A12 A11 A10 A9 A8
; after read or write by PORT #0
;-------------------------------------------
; IN:
; A = A16:4 A15:2 A14:1 (R14)
; B = A7 A6 A5 A4 A3 A2 A1 A0 (P1)
; X = 0 0 0 0 0 0 0 0 A13:32 A12:16 A11:8 ... (P1)
;-------------------------------------------
SetVDPAddress:
LDU #VDPCTRL ; adresse ecriture registre VDP
STA ,U ; WRITE data ; A==>R14
LDA #14+$80
STA ,U ; WRITE n° registre ; R14
STB ,U ; Write data
TFR X,D
ADDB #$40 ; mode ecriture
STB ,U ; Write data
RTS
;-------------------------------------------
; Attend que le VDP soit libre
;
;-------------------------------------------
WaitIntVDP:
LDU #VDPCTRL ; adresse ecriture registre VDP
LDA #$02 ; => status 02
STA ,U ; data==>R15
LDA #15+$80
STA ,U ; R15
LDA ,U
RORA ; RR A
BCS WaitIntVDP
RTS
;-------------------------------------------
; Remplir la VRAM
;-------------------------------------------
; IN:
; X = adresse des datas à charger en VRAM
; Y = longeur des données à charger
;-------------------------------------------
FillVram:
LDU #VDPDATA ; adresse ecriture P1 VDP
LoopWriteVram:
LDA ,X+
STA ,U ; Write data sur P1
LEAY -1,Y
BNE LoopWriteVram
RTS
Moving:
LDU #VDPCTRL
LDA #32
STA ,U
LDA #17+$80 ; => reg17
STA ,U ; registre n°A autoincrementé
LDU #VDPRegInd
;SX R32-33
LDA #$00
STA ,U ; 1er octet de command
LDA #$00
STA ,U ; 2eme octet de command
;SY R34-35
LDA #$00
STA ,U ; 3eme octet de command
LDA #$00
STA ,U ; 4eme octet de command
;DX R36-37
LDA #$00
STA ,U
LDA #$00
STA ,U
;DY R38-39
LDX #Coordy
LDA ,X
ADDA #$60
;LD A,$60
STA ,U
LDA #$00
STA ,U
;NX R40-41
LDA #$FF
STA ,U
LDA #$00
STA ,U
;NY R42-43
LDA #$40
STA ,U
LDA #$00
STA ,U
LDA #$00
STA ,U ; R44 null
;Command R45
LDA #$00
STA ,U
;Command R46
LDA #$D0 ;D0 HMMM 90 LMMM
STA ,U ; envoie command
JSR WaitIntVDP
LDX #Coordy
LDA ,X
INCA
CMPA #$35
BNE Paslimite
LDA #$00
Paslimite:
STA ,X
RTS
;-------------------------------------------
; Attend que le VDP soit en attente d'octets
;
;-------------------------------------------
WaitTRVDP:
LDU #VDPCTRL
LDA #$02 ; => status 02
STA ,U ; data==>R15
LDA #15+$80
STA ,U ; R15
LDA ,U
TFR A,B ; LD B,A
RORA ; RR A
BCC FinCmdTrVdp ;JP NC,FinCmdTrVdp
ROLB ; RL B
BCC WaitTRVDP ; JR NC,WaitTRVDP
FinCmdTrVdp:
RTS
SCREEN:
;************** IMAGE ******************
les datas sont dans le fichier binaire car ca va alourdir le post pour rien
J'ai vérifié qu'il n'y ai pas d'erreur d'assemblage et que les routines fonctionnent correctement,
La seule chose qu'il faut vérifier c'est la routine d'attente d'octets par le VDP, je m'en rappelle plus trop
et dans mes notes j'ai pas tout, surtout que une partie est sur un PC qui est en panne dans l'immédiat.
